目前已有若干版本的子程序庫公開發(fā)表，它們各有特色。筆者在1988年也編制了兩個子程序庫（定點(diǎn)子程序庫和浮點(diǎn)子程序庫），并在相容性、透明性、容錯性和算法優(yōu)化方面作了一些工作。本程序庫中的開平方算法為筆者研究的快速逼近算法，它能達(dá)到牛頓迭代法同樣的精度，而速度加快二十倍左右，超過雙字節(jié)定點(diǎn)除法的速度。經(jīng)過八年來全國廣大用戶的實(shí)際使用，反饋了不少信息，陸續(xù)擴(kuò)充了一些新的子程序，糾正了一些隱含錯誤，成為現(xiàn)在這個版本。

　　本子程序庫對《單片機(jī)應(yīng)用程序設(shè)計技術(shù)》一書附錄中的子程序庫作了重大修訂：

　　（１）按當(dāng)前流行的以 IBM PC 為主機(jī)的開發(fā)系統(tǒng)對匯編語言的規(guī)定，將原子程序庫的標(biāo)號和位地址進(jìn)行了調(diào)整，讀者不必再進(jìn)行修改，便可直接使用。

　　（２）對浮點(diǎn)運(yùn)算子程序庫進(jìn)行了進(jìn)一步的測試和優(yōu)化，對十進(jìn)制浮點(diǎn)數(shù)和二進(jìn)制浮點(diǎn)數(shù)的相互轉(zhuǎn)換子程序進(jìn)行了徹底改寫，提高了運(yùn)算精度和可靠性。

　　（３）新增添了若干個浮點(diǎn)子程序（傳送、比較、清零、判零等），使編寫數(shù)據(jù)處理程序的工作變得更簡單直觀。

　　在使用說明中開列了主要的幾項：標(biāo)號、入口條件、出口信息、影響資源、堆棧需求，各項目的意義請參閱《單片機(jī)應(yīng)用程序設(shè)計技術(shù)》第六章 6.3.7 節(jié)的內(nèi)容。程序清單中開列了四個欄目：標(biāo)號、指令、操作數(shù)、注釋。為方便讀者理解，注釋盡力詳細(xì)。子程序庫的使用方法如下：

　　１．將子程序庫全部內(nèi)容鏈接在應(yīng)用程序之后，統(tǒng)一編譯即可。優(yōu)點(diǎn)是簡單方便，缺點(diǎn)是程序太長，大量無關(guān)子程序也包含在其中。

　　２．僅將子程序庫中的有關(guān)部分內(nèi)容鏈接在應(yīng)用程序之后，統(tǒng)一編譯即可。有些子程序需要調(diào)用一些低級子程序，這些低級子程序也應(yīng)該包含在內(nèi)。優(yōu)點(diǎn)是程序緊湊，缺點(diǎn)是需要對子程序庫進(jìn)行仔細(xì)刪節(jié)。

　　（一）ＭＣＳ－５１定點(diǎn)運(yùn)算子程序庫及其使用說明

　　定點(diǎn)運(yùn)算子程序庫文件名為DQ51.ASM，為便于使用，先將有關(guān)約定說明如下：

　　１．多字節(jié)定點(diǎn)操作數(shù)：用[R0]或[R1]來表示存放在由R0或R1指示的連續(xù)單元中的數(shù)據(jù)。地址小的單元存放數(shù)據(jù)的高字節(jié)。例如：[R0]=123456H，若(R0)=30H，則(30H)=12H，(31H)=34H，(32H)=56H。

　　２．運(yùn)算精度：單次定點(diǎn)運(yùn)算精度為結(jié)果位的當(dāng)量值。

　　３．工作區(qū)：數(shù)據(jù)工作區(qū)固定在PSW、A、B、R2～R7，用戶只要不在工作區(qū)中存放無關(guān)的或非消耗性的信息，程序就具有較好的透明性。

（１） 標(biāo)號： ＢＣＤＡ功能：多字節(jié)ＢＣＤ碼加法

入口條件：字節(jié)數(shù)在R7中，被加數(shù)在[R0]中，加數(shù)在[R1]中。
出口信息：和在[R0]中，位進(jìn)位在CY中。
影響資源：PSW、A、R2 堆棧需求： ２字節(jié)

BCDA: MOV A,R7 ；取字節(jié)數(shù)至R2中
MOV R2,A
ADD A,R0 ；初始化數(shù)據(jù)指針
MOV R0,A
MOV A,R2
ADD A,R1
MOV R1,A
CLR C
BCD1: DEC R0 ；調(diào)整數(shù)據(jù)指針
DEC R1
MOV A,@R0
ADDC A,@R1 ；按字節(jié)相加
DA A ；十進(jìn)制調(diào)整
MOV @R0,A ；和存回[R0]中
DJNZ R2,BCD1 ；處理完所有字節(jié)
RET

（２） 標(biāo)號： ＢＣＤＢ功能：多字節(jié)ＢＣＤ碼減法

入口條件：字節(jié)數(shù)在R7中，被減數(shù)在[R0]中，減數(shù)在[R1]中。
出口信息：差在[R0]中，位借位在CY中。
影響資源：PSW、A、R2、R3 堆棧需求： ６字節(jié)

BCDB: LCALL NEG1 ；減數(shù)[R1]十進(jìn)制取補(bǔ)
LCALL BCDA ；按多字節(jié)ＢＣＤ碼加法處理
CPL C ；將補(bǔ)碼加法的進(jìn)位標(biāo)志轉(zhuǎn)換成借位標(biāo)志
MOV F0,C ；保護(hù)借位標(biāo)志
LCALL NEG1 ；恢復(fù)減數(shù)[R1]的原始值
MOV C,F0 ；恢復(fù)借位標(biāo)志
RET
NEG1: MOV A,R0 ；[R1]十進(jìn)制取補(bǔ)子程序入口
XCH A,R1 ；交換指針
XCH A,R0
LCALL NEG ；通過[R0]實(shí)現(xiàn)[R1]取補(bǔ)
MOV A,R0
XCH A,R1 ；換回指針
XCH A,R0
RET


（３） 標(biāo)號： ＮＥＧ功能：多字節(jié)ＢＣＤ碼取補(bǔ)

入口條件：字節(jié)數(shù)在R7中，操作數(shù)在[R0]中。
出口信息：結(jié)果仍在[R0]中。
影響資源：PSW、A、R2、R3 堆棧需求： ２字節(jié)

NEG: MOV A,R7 ；取（字節(jié)數(shù)減一）至R2中
DEC A
MOV R2,A
MOV A,R0 ；保護(hù)指針
MOV R3,A
NEG0: CLR C
MOV A,#99H
SUBB A,@R0 ；按字節(jié)十進(jìn)制取補(bǔ)
MOV @R0,A ；存回[R0]中
INC R0 ；調(diào)整數(shù)據(jù)指針
DJNZ R2,NEG0 ；處理完（R2）字節(jié)
MOV A,#9AH ；字節(jié)單獨(dú)取補(bǔ)
SUBB A,@R0
MOV @R0,A
MOV A,R3 ；恢復(fù)指針
MOV R0,A
RET

（４） 標(biāo)號： ＢＲＬＮ功能：多字節(jié)ＢＣＤ碼左移十進(jìn)制一位（乘十）

入口條件：字節(jié)數(shù)在R7中，操作數(shù)在[R0]中。
出口信息：結(jié)果仍在[R0]中，移出的十進(jìn)制位在R3中。
影響資源：PSW、A、R2、R3 堆棧需求： ２字節(jié)

BRLN: MOV A,R7 ；取字節(jié)數(shù)至R2中
MOV R2,A
ADD A,R0 ；初始化數(shù)據(jù)指針
MOV R0,A
MOV R3,#0 ；工作單元初始化
BRL1: DEC R0 ；調(diào)整數(shù)據(jù)指針
MOV A,@R0 ；取一字節(jié)
SWAP A ；交換十進(jìn)制高低位
MOV @R0,A ；存回
MOV A,R3 ；取低字節(jié)移出的十進(jìn)制高位
XCHD A,@R0 ；換出本字節(jié)的十進(jìn)制高位
MOV R3,A ；保存本字節(jié)的十進(jìn)制高位
DJNZ R2,BRL1 ；處理完所有字節(jié)
RET

（５） 標(biāo)號： ＭＵＬＤ功能：雙字節(jié)二進(jìn)制無符號數(shù)乘法

入口條件：被乘數(shù)在R2、R3中，乘數(shù)在R6、R7中。
出口信息：乘積在R2、R3、R4、R5中。
影響資源：PSW、A、B、R2～R7 堆棧需求： ２字節(jié)

MULD: MOV A,R3 ；計算R3乘R7
MOV B,R7
MUL AB
MOV R4,B ；暫存部分積
MOV R5,A
MOV A,R3 ；計算R3乘R6
MOV B,R6
MUL AB
ADD A,R4 ；累加部分積
MOV R4,A
CLR A
ADDC A,B
MOV R3,A
MOV A,R2 ；計算R2乘R7
MOV B,R7
MUL AB
ADD A,R4 ；累加部分積
MOV R4,A
MOV A,R3
ADDC A,B
MOV R3,A
CLR A
RLC A
XCH A,R2 ；計算R2乘R6
MOV B,R6
MUL AB
ADD A,R3 ；累加部分積
MOV R3,A
MOV A,R2
ADDC A,B
MOV R2,A
RET

（６） 標(biāo)號： ＭＵＬ２功能：雙字節(jié)二進(jìn)制無符號數(shù)平方

入口條件：待平方數(shù)在R2、R3中。
出口信息：結(jié)果在R2、R3、R4、R5中。
影響資源：PSW、A、B、R2～R5 堆棧需求： ２字節(jié)

MUL2: MOV A,R3 ；計算R3平方
MOV B,A
MUL AB
MOV R4,B ；暫存部分積
MOV R5,A
MOV A,R2 ；計算R2平方
MOV B,A
MUL AB
XCH A,R3 ；暫存部分積，并換出R2和R3
XCH A,B
XCH A,R2
MUL AB ；計算2×R2×R3
CLR C
RLC A
XCH A,B
RLC A
JNC MU20
INC R2 ；累加溢出量
MU20: XCH A,B ；累加部分積
ADD A,R4
MOV R4,A
MOV A,R3
ADDC A,B
MOV R3,A
CLR A
ADDC A,R2
MOV R2,A
RET

（７） 標(biāo)號： ＤＩＶＤ功能：雙字節(jié)二進(jìn)制無符號數(shù)除法

入口條件：被除數(shù)在R2、R3、R4、R5中，除數(shù)在R6、R7中。
出口信息：OV=0 時，雙字節(jié)商在R2、R3中，OV=1 時溢出。
影響資源：PSW、A、B、R1～R7 堆棧需求： ２字節(jié)

DIVD: CLR C ；比較被除數(shù)和除數(shù)
MOV A,R3
SUBB A,R7
MOV A,R2
SUBB A,R6
JC DVD1
SETB OV ；溢出
RET
DVD1: MOV B,#10H ；計算雙字節(jié)商
DVD2: CLR C ；部分商和余數(shù)同時左移一位
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
XCH A,R2
RLC A
XCH A,R2
MOV F0,C ；保存溢出位
CLR C
SUBB A,R7 ；計算（R2R3－R6R7）
MOV R1,A
MOV A,R2
SUBB A,R6
ANL C,/F0 ；結(jié)果判斷
JC DVD3
MOV R2,A ；夠減，存放新的余數(shù)
MOV A,R1
MOV R3,A
INC R5 ；商的低位置一
DVD3: DJNZ B,DVD2 ；計算完十六位商（R4R5）
MOV A,R4 ；將商移到R2R3中
MOV R2,A
MOV A,R5
MOV R3,A
CLR OV ；設(shè)立成功標(biāo)志
RET

（８） 標(biāo)號： Ｄ４５７功能：雙字節(jié)二進(jìn)制無符號數(shù)除以單字節(jié)二進(jìn)制數(shù)

入口條件：被除數(shù)在R4、R5中，除數(shù)在R7中。
出口信息：OV=0 時，單字節(jié)商在R3中，OV=1 時溢出。
影響資源：PSW、A、R3～R7 堆棧需求： ２字節(jié)

D457: CLR C
MOV A,R4
SUBB A,R7
JC DV50
SETB OV ；商溢出
RET
DV50: MOV R6,#8 ；求平均值（R4R5／R7－→R3）
DV51: MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DV52
MOV R4,A
DV52: CPL C
MOV A,R3
RLC A
MOV R3,A
DJNZ R6,DV51
MOV A,R4 ；四舍五入
ADD A,R4
JC DV53
SUBB A,R7
JC DV54
DV53: INC R3
DV54: CLR OV
RET

（９） 標(biāo)號： ＤＶ３１功能：三字節(jié)二進(jìn)制無符號數(shù)除以單字節(jié)二進(jìn)制數(shù)

入口條件：被除數(shù)在R3、R4、R5中，除數(shù)在R7中。
出口信息：OV=0 時，雙字節(jié)商在R4、R5中，OV=1 時溢出。
影響資源：PSW、A、B、R2～R7 堆棧需求： ２字節(jié)

DV31: CLR C
MOV A,R3
SUBB A,R7
JC DV30
SETB OV ；商溢出
RET
DV30: MOV R2,#10H ；求R3R4R5／R7－→R4R5
DM23: CLR C
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DM24
MOV R3,A
INC R5
DM24: DJNZ R2,DM23
MOV A,R3 ；四舍五入
ADD A,R3
JC DM25
SUBB A,R7
JC DM26
DM25: INC R5
MOV A,R5
JNZ DM26
INC R4
DM26: CLR OV
RET ；商在R4R5中


（１０） 標(biāo)號： ＭＵＬＳ功能：雙字節(jié)二進(jìn)制有符號數(shù)乘法（補(bǔ)碼）

入口條件：被乘數(shù)在R2、R3中，乘數(shù)在R6、R7中。
出口信息：乘積在R2、R3、R4、R5中。
影響資源：PSW、A、B、R2～R7 堆棧需求： ４字節(jié)

MULS: MOV R4,#0 ；清零R4R5
MOV R5,#0
LCALL MDS ；計算結(jié)果的符號和兩個操作數(shù)的值
LCALL MULD ；計算兩個值的乘積
SJMP MDSE ；用補(bǔ)碼表示結(jié)果

（１１） 標(biāo)號： ＤＩＶＳ功能：雙字節(jié)二進(jìn)制有符號數(shù)除法（補(bǔ)碼）

入口條件：被除數(shù)在R2、R3、R4、R5中，除數(shù)在R6、R7中。
出口信息：OV=0時商在R2、R3中，OV=1時溢出。
影響資源：PSW、A、B、R1～R7 堆棧需求： ５字節(jié)

DIVS: LCALL MDS ；計算結(jié)果的符號和兩個操作數(shù)的值
PUSH PSW ；保存結(jié)果的符號
LCALL DIVD ；計算兩個值的商
JNB OV,DVS1 ；溢出否？
POP ACC ；溢出，放去結(jié)果的符號，保留溢出標(biāo)志
RET
DVS1: POP PSW ；未溢出，取出結(jié)果的符號
MOV R4,#0
MOV R5,#0
MDSE: JB F0,MDS2 ；用補(bǔ)碼表示結(jié)果
CLR OV ；結(jié)果為正，原碼即補(bǔ)碼，計算成功
RET
MDS: CLR F0 ；結(jié)果符號初始化
MOV A,R6 ；判斷第二操作數(shù)的符號
JNB ACC.7,MDS1；為正，不必處理
CPL F0 ；為負(fù)，結(jié)果符號取反
XCH A,R7 ；第二操作數(shù)取補(bǔ)，得到其值
CPL A
ADD A,#1
XCH A,R7
CPL A
ADDC A,#0
MOV R6,A
MDS1: MOV A,R2 ；判斷操作數(shù)或運(yùn)算結(jié)果的符號
JNB ACC.7,MDS3；為正，不必處理
CPL F0 ；為負(fù)，結(jié)果符號取反
MDS2: MOV A,R5 ；求操作數(shù)的值或運(yùn)算結(jié)果的補(bǔ)碼
CPL A
ADD A,#1
MOV R5,A
MOV A,R4
CPL A
ADDC A,#0
MOV R4,A
MOV A,R3
CPL A
ADDC A,#0
MOV R3,A
MOV A,R2
CPL A
ADDC A,#0
MOV R2,A
MDS3: CLR OV ；運(yùn)算成功
RET

（１２） 標(biāo)號： ＳＨ２功能：雙字節(jié)二進(jìn)制無符號數(shù)開平方（快速）

入口條件：被開方數(shù)在R2、R3中。
出口信息：平方根仍在R2、R3中，整數(shù)部分的位數(shù)為原數(shù)的一半，其余為小數(shù)。
影響資源：PSW、A、B、R2～R7 堆棧需求： ２字節(jié)

SH2: MOV A,R2
ORL A,R3
JNZ SH20
RET ；被開方數(shù)為零，不必運(yùn)算
SH20: MOV R7,#0 ；左規(guī)次數(shù)初始化
MOV A,R2
SH22: ANL A,#0C0H ；被開方數(shù)高字節(jié)小于４０Ｈ否？
JNZ SQRH ；不小于４０Ｈ，左規(guī)格化完成，轉(zhuǎn)開方過程
CLR C ；每左規(guī)一次，被開方數(shù)左移兩位
MOV A,R3
RLC A
MOV F0,C
CLR C
RLC A
MOV R3,A
MOV A,R2
MOV ACC.7,C
MOV C,F0
RLC A
RLC A
MOV R2,A
INC R7 ；左規(guī)次數(shù)加一
SJMP SH22 ；繼續(xù)左規(guī)

（１３） 標(biāo)號： ＳＨ４功能：四字節(jié)二進(jìn)制無符號數(shù)開平方（快速）

入口條件：被開方數(shù)在R2、R3、R4、R5中。
出口信息：平方根在R2、R3中，整數(shù)部分的位數(shù)為原數(shù)的一半，其余為小數(shù)。
影響資源：PSW、A、B、R2～R7 堆棧需求： ２字節(jié)

SH4: MOV A,R2
ORL A,R3
ORL A,R4
ORL A,R5
JNZ SH40
RET ；被開方數(shù)為零，不必運(yùn)算
SH40: MOV R7,#0 ；左規(guī)次數(shù)初始化
MOV A,R2
SH41: ANL A,#0C0H ；被開方數(shù)高字節(jié)小于４０Ｈ否？
JNZ SQRH ；不小于４０Ｈ，左規(guī)格化完成
MOV R6,#2 ；每左規(guī)一次，被開方數(shù)左移兩位
SH42: CLR C ；被開方數(shù)左移一位
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
MOV A,R2
RLC A
MOV R2,A
DJNZ R6,SH42 ；被開方數(shù)左移完兩位
INC R7 ；左規(guī)次數(shù)加一
SJMP SH41 ；繼續(xù)左規(guī)
SQRH: MOV A,R2 ；規(guī)格化后高字節(jié)按折線法分為三個區(qū)間
ADD A,#57H
JC SQR2
ADD A,#45H
JC SQR1
ADD A,#24H
MOV B,#0E3H ；區(qū)間的斜率
MOV R4,#80H ；區(qū)間的平方根基數(shù)
SJMP SQR3
SQR1: MOV B,#0B2H ；第二區(qū)間的斜率
MOV R4,#0A0H；第二區(qū)間的平方根基數(shù)
SJMP SQR3
SQR2: MOV B,#8DH ；第三區(qū)間的斜率
MOV R4,#0D0H；第三區(qū)間的平方根基數(shù)
SQR3: MUL AB ；與區(qū)間基點(diǎn)的偏移量乘區(qū)間斜率
MOV A,B
ADD A,R4 ；累加到平方根的基數(shù)上
MOV R4,A
MOV B,A
MUL AB ；求當(dāng)前平方根的冪
XCH A,R3 ；求偏移量（存放在R2R3中）
CLR C
SUBB A,R3
MOV R3,A
MOV A,R2
SUBB A,B
MOV R2,A
SQR4: SETB C ；用減奇數(shù)法校正一個字節(jié)的平方根
MOV A,R4 ；當(dāng)前平方根的兩倍加一存入R5R6中
RLC A
MOV R6,A
CLR A
RLC A
MOV R5,A
MOV A,R3 ；偏移量小于該奇數(shù)否？
SUBB A,R6
MOV B,A
MOV A,R2
SUBB A,R5
JC SQR5 ；小于，校正結(jié)束，已達(dá)到一個字節(jié)的精度
INC R4 ；不小于，平方根加一
MOV R2,A ；保存新的偏移量
MOV R3,B
SJMP SQR4 ；繼續(xù)校正
SQR5: MOV A,R4 ；將一個字節(jié)精度的根存入R2
XCH A,R2
RRC A
MOV F0,C ；保存終偏移量的位
MOV A,R3
MOV R5,A ；將終偏移量的低八位存入R5中
MOV R4,#8 ；通過（R5R6／R2）求根的低字節(jié)
SQR6: CLR C
MOV A,R3
RLC A
MOV R3,A
CLR C
MOV A,R5
SUBB A,R2
JB F0,SQR7
JC SQR8
SQR7: MOV R5,A
INC R3
SQR8: CLR C
MOV A,R5
RLC A
MOV R5,A
MOV F0,C
DJNZ R4,SQR6 ；根的第二字節(jié)計算完，在R3中
MOV A,R7 ；取原被開方數(shù)的左規(guī)次數(shù)
JZ SQRE ；未左規(guī)，開方結(jié)束
SQR9: CLR C ；按左規(guī)次數(shù)右移平方根，得到實(shí)際根
MOV A,R2
RRC A
MOV R2,A
MOV A,R3
RRC A
MOV R3,A
DJNZ R7,SQR9
SQRE: RET

（１４） 標(biāo)號： ＨＡＳＣ功能：單字節(jié)十六進(jìn)制數(shù)轉(zhuǎn)換成雙字節(jié)ASCII碼

入口條件：待轉(zhuǎn)換的單字節(jié)十六進(jìn)制數(shù)在累加器A中。
出口信息：高四位的ASCII碼在A中，低四位的ASCII碼在B中。
影響資源：PSW、A、B 堆棧需求： ４字節(jié)

HASC: MOV B,A ；暫存待轉(zhuǎn)換的單字節(jié)十六進(jìn)制數(shù)
LCALL HAS1 ；轉(zhuǎn)換低四位
XCH A,B ；存放低四位的ASCII碼
SWAP A ；準(zhǔn)備轉(zhuǎn)換高四位
HAS1: ANL A,#0FH ；將累加器的低四位轉(zhuǎn)換成ASCII碼
ADD A,#90H
DA A
ADDC A,#40H
DA A
RET

（１５） 標(biāo)號： ＡＳＣＨ 功能：ASCII碼轉(zhuǎn)換成十六進(jìn)制數(shù)

入口條件：待轉(zhuǎn)換的ASCII碼（30H～39H或41H～46H）在A中。
出口信息：轉(zhuǎn)換后的十六進(jìn)制數(shù)（00H～0FH）仍在累加器A中。
影響資源：PSW、A 堆棧需求： ２字節(jié)

ASCH: CLR C
SUBB A,#30H
JNB ACC.4,ASH1
SUBB A,#7
ASH1: RET